Once the software and links are set up properly, download the software and the configuration to the TX board by using the monload batch file. The monload file accepts the board number to load. This loader file resets the TX board and downloads the necessary software to the TX board, including support tasks for alarms and debugging, and the monitor task. Finally, the configuration for the monitor task is downloaded.
The following sample code is a Windows version of monload.bat:
@echo off
REM ***************************************************************************
REM TX Series COMMUNICATIONS PROCESSOR BOOT FILE (MONITOR)
REM
REM Execute this file to perform the following:
REM - Reset the TX board
REM - Synchronize the on-board flash image with the installed software
REM - Download TDM configuration
REM - Download all TX-based tasks
REM - Configure MONITOR
REM ***************************************************************************
if "%DIALOGIC_ROOT%"=="" set DIALOGIC_ROOT=\Program Files\Dialogic
if "%TX_ROOT%"=="" set TX_ROOT=%DIALOGIC_ROOT%\tx
REM ***************************************************************************
REM Define all other script parameters
REM
if "%TXCONFIG%"=="" set TXCONFIG=%TX_ROOT%\config
if "%TXUTIL%"=="" set TXUTIL=%TX_ROOT%\bin
if "%TXCP%"=="" set TXCP=%TX_ROOT%\cp
REM ***************************************************************************
REM Process arguments - Get the board number
REM
set BRD=1
if not "%1"=="" set BRD=%1
REM ***************************************************************************
REM Clear driver statistics
REM
"%TXUTIL%\txstats" -b %BRD% -z -q
REM ***************************************************************************
REM Get the model number (TX board type)
REM
"%TXUTIL%\cpmodel" -b %BRD%
if %errorlevel% == 4000 goto set4000
if %errorlevel% == 5000 goto set5000
if %errorlevel% == 5020 goto set5000
if %errorlevel% == 5500 goto set5000
echo ERROR! TX board number %BRD% not available.
goto end
REM ***************************************************************************
REM Setup for TX 4000 Family
REM
:set4000
set TASKTYPE=elf
set TXKERNEL=cpk4000.fls
goto resetboard
REM ***************************************************************************
REM Setup for TX 5000 Family
REM
:set5000
set TASKTYPE=elf
set TXKERNEL=cpk5000.elf
REM ***************************************************************************
REM Reset the TX board
REM
:resetboard
REM Reset TX board (and verify TX flash image in sync with installed software)
"%TXUTIL%\txflash" -s "%TXCP%\%TXKERNEL%" -b %BRD%
if %errorlevel% == 1 goto failedreset
REM ***************************************************************************
REM Enable the following to use txmon
REM
REM "%TXUTIL%\cplot" -c %BRD% -f "%TXCP%\txmon.%TASKTYPE%" -n txmon -p 19 -a
REM ***************************************************************************
REM Load TDM configuration
REM
"%TXUTIL%\txconfig" -b %BRD% -f "%TXCONFIG%\txcfg%BRD%.txt"
REM ***************************************************************************
REM Load the monitor layer
REM
"%TXUTIL%\cplot" -c %BRD% -f "%TXCP%\monitor.%TASKTYPE%" -n monitor -p 20 -a -s 12000
REM ***************************************************************************
REM Configure the monitor layer
REM
"%TXUTIL%\moncfg" -b %BRD% -f "%TXCONFIG%\MONcp%BRD%.cfg"
goto end
REM ***************************************************************************
REM Report reset error
REM
:failedreset
echo ERROR! Unable to reset TX board number %BRD%.
goto end
REM ***************************************************************************
REM Exit load script
:end
set TXUTIL=
set TXCP=
set TXCONFIG=
set BRD=
set TASKTYPE=
set TXKERNEL=
The txalarm utility is also included to help debug the configuration and user applications. For more information, refer to the Dialogic® TX Series SS7 Boards TX Utilities Manual.
Board loaded:
<06/10/2002 11:12:39> monitor 3 1 Monitor task initialized!