After installing the TX board and the software, configure MTP 2 as follows:
If the TX board running the MTP 2 task sends and receives on a T1 or E1 timeslot, configure the TDM ports that the MTP 2 task uses. NMS SS7 provides sample TDM configuration files for ANSI standalone and redundant configurations and ITU standalone and redundant configurations. On a Windows operating system, the files are tdmcp1and tdmcp2, located in \nms\tx\config\. On a UNIX system, the files are TDMcp1 and TDMcp2, and are located in /opt/nmstx/etc/. You can modify these files for your specifications.
For more information on configuring TDM ports, see the NMS SS7 Configuration Manual.
MTP 2 allows applications to configure the number of links and the parameters associated with those links. NMS SS7 provides sample link configuration files for ANSI standalone and redundant configurations and ITU standalone and redundant configurations. These files support back-to-back configurations. They contain a definition for one TDM port and a commented-out V.35 port. If the installation uses V.35 ports, comment in the example serial port definition in the file and comment out the TDM port.
On a Windows operating system, the files are mtp3cp1 and mtp3cp2, located in \nms\tx\config\. On a UNIX system, the files are MTP3cp1 and MTP3cp2, and are located in /opt/nmstx/etc/.
For more information on configuring MTP 2 links, see the NMS SS7 Configuration Manual.
After you configure the TDM ports and links, download the configuration to the TX board using mtp2load. mtp2load accepts one parameter, the board number to load. mtp2load downloads the following software to the TX board:
The proper kernel
Support tasks for alarms and debugging
A console program
The T1/E1 managers
The MTP 2 task
The MTP 2 configuration
mtp2load is located in \nms\tx\bin on the Windows operating system and in /opt/nmstx/bin on the UNIX operating systems.
@echo off
REM ***************************************************************************
REM TX Series COMMUNICATIONS PROCESSOR BOOT FILE (MTP2)
REM
REM Execute this file to perform the following:
REM - Reset the TX board
REM - Synchronize the on-board flash image with the installed software
REM - Download TDM configuration
REM - Download all TX-based tasks
REM - Configure MTP
REM ***************************************************************************
REM ***************************************************************************
REM Define all script parameters
REM
set TXUTIL=\nms\tx\bin
set TXCP=\nms\tx\cp
set TXCONFIG=\nms\tx\config\ansi
REM ***************************************************************************
REM Process arguments - Get the board number
REM
set BRD=1
if not "%1"=="" set BRD=%1
REM ***************************************************************************
REM Clear driver statistics
REM
%TXUTIL%\txstats -b %BRD% -z -q
REM ***************************************************************************
REM Get the model number (TX board type)
REM
%TXUTIL%\cpmodel -b %BRD%
if errorlevel 4000 goto boot4000
if errorlevel 3220 goto boot3220
echo ERROR! TX board number %BRD% not available.
goto end
REM ***************************************************************************
REM Perform board type-specific boot for TX 3220 or TX 3220C
REM
:boot3220
set TASKTYPE=lot
REM Reset TX board (and verify TX flash image in sync with installed software)
%TXUTIL%\txflash -s %TXCP%\cpk3220.bin -b %BRD%
if errorlevel 1 goto failedreset
REM load the diagnostic operator console task
%TXUTIL%\cplot -c %BRD% -f %TXCP%\diag3220.lot -n diag -p 2 -a
REM load TDM configuration
%TXUTIL%\cplot -c %BRD% -f %TXCONFIG%\TDMcp%BRD%.bin -g tdm
REM load ARP and INF (alarm forwarding task)
%TXUTIL%\cplot -c %BRD% -f %TXCP%\arp.lot -n arp -p 17 -a
%TXUTIL%\cplot -c %BRD% -f %TXCP%\inf.lot -n inf -p 16 -a
REM load the MVIP and T1/E1 manager tasks to enable use
REM of the MVIP and T1/E1 host APIs; NOTE: if you do not
REM use either of these APIs, remove the following 2 lines.
%TXUTIL%\cplot -c %BRD% -f %TXCP%\mvip.lot -n mvip -p 4 -a
%TXUTIL%\cplot -c %BRD% -f %TXCP%\t1e1mgr.lot -n t1e1mgr -p 15 -a
REM To enable packet tracing in the ISUP or TUP layer, make the following
REM command active to download the ETP trace collector on the board.
REM %TXUTIL%\cplot -c %BRD% -f %TXCP%\etp.lot -n etp -p 14 -a
goto loadcommon
REM ***************************************************************************
REM Perform board type-specific boot for TX 4000
REM
:boot4000
set TASKTYPE=elf
REM Reset TX board (and verify TX flash image in sync with installed software)
%TXUTIL%\txflash -s %TXCP%\cpk4000.fls -b %BRD%
if errorlevel 1 goto failedreset
REM load TDM configuration
%TXUTIL%\txconfig -b %BRD% -f %TXCONFIG%\txcfg%BRD%.txt
goto loadcommon
REM ***************************************************************************
REM Load all TX-based tasks that are common to all board types
REM
:loadcommon
REM To use txdbg,
REM you should uncomment the following line to load the debug task
REM %TXUTIL%\cplot -c %BRD% -f %TXCP%\debug.%TASKTYPE% -n debug -p 11 -a
REM Load MTP12 task
REM
%TXUTIL%\cplot -c %BRD% -f %TXCP%\mtp12.%TASKTYPE% -n mtp -p 20 -a -s 12000
REM ***************************************************************************
REM Configure SS7 MTP2
REM
%TXUTIL%\mtp2cfg -b %BRD% -f %TXCONFIG%\MTP2cp%BRD%.cfg
goto end
REM ***************************************************************************
REM Report reset error
REM
:failedreset
echo ERROR! Unable to reset TX board number %BRD%.
goto end
REM ***************************************************************************
REM Exit load script
:end
set TXMODE=
set TXUTIL=
set TXCP=
set TXCONFIG=
set BRD=
set TASKTYPE=
#!/bin/ksh
#******************************************************************************
# TX Series COMMUNICATIONS PROCESSOR BOOT FILE (MTP2)
#
# Execute this file to perform the following:
# - Reset the TX board
# - Synchronize the on-board flash image with the installed software
# - Download TDM configuration
# - Download all TX-based tasks
# - Configure MTP
#******************************************************************************
#******************************************************************************
# Define all script parameters
#
if [ -z "$TXUTIL" ]
then
TXUTIL=/opt/nmstx/bin
fi
if [ -z "$TXBASE" ]
then
TXBASE=/opt/nmstx/cp
fi
if [ -z "$TXCONFIG" ]
then
TXCONFIG=/opt/nmstx/etc/ansi
fi
#******************************************************************************
# Process arguments - Get the board number
#
case $# in
0)
BRD=1
;;
1)
BRD=$1
;;
*)
echo "Usage: mtp2load <board#>"
exit 1
esac
#******************************************************************************
# Clear driver statistics
#
$TXUTIL/txstats -b $BRD -z -q
#******************************************************************************
# Get the model number (TX board type)
#
BOARDTYPE=`$TXUTIL/cpmodel -b$BRD | tail -1 | cut -d' ' -f5`
case $BOARDTYPE in
TX4000)
FLASH="cpk4000.fls"
;;
TX3220)
FLASH="cpk3220.bin"
;;
*)
echo "ERROR! Board number $BRD not available"
exit 1
;;
esac
#*****************************************************************************
# Reset TX board (and verify TX flash image in sync with installed software)
#
$TXUTIL/txflash -s $TXBASE/$FLASH -b$BRD
#*****************************************************************************
# Perform TX board type-specific load
#
if [ $BOARDTYPE = "TX3220" ]
then
# Perform board type-specific boot for TX 3220 or TX 3220C
TASKTYPE=lot
# load the diagnostic operator console task
$TXUTIL/cplot -c $BRD -f $TXBASE/diag3220.lot -n diag -p 2 -a
# load TDM configuration
$TXUTIL/cplot -c $BRD -f $TXCONFIG/TDMcp${BRD}.bin -g tdm
# load ARP and INF (alarm forwarding task)
$TXUTIL/cplot -c $BRD -f $TXBASE/arp.lot -n arp -p 17 -a
$TXUTIL/cplot -c $BRD -f $TXBASE/inf.lot -n inf -p 16 -a
# load the MVIP and T1/E1 manager tasks to enable use
# of the MVIP and T1/E1 host APIs. Note: if you do not
# use either of these APIs, remove the following two lines
$TXUTIL/cplot -c $BRD -f $TXBASE/mvip.lot -n mvip -p 4 -a
$TXUTIL/cplot -c $BRD -f $TXBASE/t1e1mgr.lot -n t1e1mgr -p 15 -a
# To enable packet tracing in the ISUP or TUP layer, make the following
# command active to download the ETP trace collector on the board.
# $TXUTIL/cplot -c $BRD -f $TXBASE/etp.lot -n etp -p 14 -a
else
# Perform board type-specific boot for TX 4000
TASKTYPE=elf
# load TDM configuration
$TXUTIL/txconfig -b $BRD -f $TXCONFIG/txcfg$BRD.txt
fi
#*****************************************************************************
# Load all TX-based tasks that are common to all board types
#
# To use txdbg,
# you should uncomment the following line to load the debug task
#$TXUTIL/cplot -c $BRD -f $TXBASE/debug.$TASKTYPE -n debug -p 11 -a
# Load MTP task
#
$TXUTIL/cplot -c $BRD -f $TXBASE/mtp12.$TASKTYPE -n mtp -p 20 -a -s 12000
#******************************************************************************
# Configure SS7 MTP2
#
$TXUTIL/mtp2cfg -b $BRD -f $TXCONFIG/MTP2cp${BRD}.cfg
#******************************************************************************
# Exit load script
exit 0
The txalarm utility captures messages from the boards, displays them on the screen, and optionally saves them to a disk file. txalarm is the primary tool for monitoring what is happening on the link as you download the board and bring links up.
Run txalarm from a separate window according to the following syntax:
txalarm [-f filename]
where -f filename specifies the file to which messages are copied.
The following example shows txalarm messages when the board is downloaded without sending a new MTP 2 configuration. This shows only the first four links for brevity. There can be alarms for up to 32 links.
<07/25/06 14:52:25> mtp 1 16387 Registering MTP Layer 2
<07/25/06 14:52:25> mtp 1 16387 Configuring MTP Layer 1
<07/25/06 14:52:25> mtp 1 16387 MTP1 Initializing.
<07/25/06 14:52:25> mtp 1 16387 MTP1 General Configuration
<07/25/06 14:52:25> mtp 1 16387 MTP1 Configuring link 0: TDM, External
<07/25/06 14:52:25> mtp 1 16387 MTP1 Configuring link 1: TDM, External
<07/25/06 14:52:25> mtp 1 16387 MTP1 Configuring link 2: TDM, External
<07/25/06 14:52:25> mtp 1 16387 MTP1 Configuring link 3: TDM, External
<07/25/06 14:52:25> mtp 1 16387 Configuring MTP Layer 2
<07/25/06 14:52:25> mtp 1 16387 MTP2: General Configuration
<07/25/06 14:52:25> mtp 1 16387 MTP2: Link 0 Configuration
<07/25/06 14:52:25> mtp 1 16387 MTP2: Link 1 Configuration
<07/25/06 14:52:25> mtp 1 16387 MTP2: Link 2 Configuration
<07/25/06 14:52:25> mtp 1 16387 MTP2: Link 3 Configuration
After the board is loaded, start the demonstration program. mtp2app is an ANSI version and mtp2itu is an ITU-T (formerly CCITT) version of the demonstration program. See Using the MTP 2 standalone task: mtp2app and mtp2itu for more details.
If you are using the TX board with test equipment, run an application then press Enter to display a command prompt. Enter connect 0 to start the connect procedure on link 0. The txalarm messages look like the following sample if the link aligns properly:
<07/25/06 15:30:08> mtp 1 16387 Flushing Buffers (OutPktCnt=0) (Lnk 0)
<07/25/06 15:30:08> mtp 1 16387 Sent SIOS (Lnk 0) (Start in PowerOff)
<07/25/06 15:30:08> mtp 1 16387 Flushing Buffers (OutPktCnt=0) (Lnk 0)
<07/25/06 15:30:08> mtp 1 16387 Starting Alignment (Lnk 0)
<07/25/06 15:30:08> mtp 1 16387 Sent SIO (Lnk 0)
<07/25/06 15:30:08> mtp 1 16387 Rcvd SIO (Lnk 0)
<07/25/06 15:30:08> mtp 1 16387 Sent SIN (Lnk 0)
<07/25/06 15:30:08> mtp 1 16387 Rcvd SIO (Lnk 0)
<07/25/06 15:30:08> mtp 1 16387 Rcvd SIN (Lnk 0)
<07/25/06 15:30:11> mtp 1 16387 Timer 4 Expired (LINK 0 ALIGNED at layer 2)
If you are using two TX boards back-to-back, after downloading each board separately, start an application on each board (for example, mtp2app -b 2 to run on board 2), and enter connect 0 on each board. The txalarm messages look like the following sample if the link aligns properly:
<07/25/06 15:30:08> mtp 1 16387 Flushing Buffers (OutPktCnt=0) (Lnk 0)
<07/25/06 15:30:08> mtp 1 16387 Sent SIOS (Lnk 0) (Start in PowerOff)
<07/25/06 15:30:08> mtp 1 16387 Flushing Buffers (OutPktCnt=0) (Lnk 0)
<07/25/06 15:30:08> mtp 1 16387 Starting Alignment (Lnk 0)
<07/25/06 15:30:08> mtp 1 16387 Sent SIO (Lnk 0)
<07/25/06 15:30:08> mtp 1 16387 Rcvd SIO (Lnk 0)
<07/25/06 15:30:08> mtp 1 16387 Sent SIN (Lnk 0)
<07/25/06 15:30:08> mtp 1 16387 Rcvd SIO (Lnk 0)
<07/25/06 15:30:08> mtp 1 16387 Rcvd SIN (Lnk 0)
<07/25/06 15:30:08> mtp 2 16387 Flushing Buffers (OutPktCnt=0) (Lnk 0)
<07/25/06 15:30:08> mtp 2 16387 Sent SIOS (Lnk 0) (Start in PowerOff)
<07/25/06 15:30:08> mtp 2 16387 Flushing Buffers (OutPktCnt=0) (Lnk 0)
<07/25/06 15:30:08> mtp 2 16387 Starting Alignment (Lnk 0)
<07/25/06 15:30:08> mtp 2 16387 Sent SIO (Lnk 0)
<07/25/06 15:30:09> mtp 2 16387 Rcvd SIOS (Lnk 0)
<07/25/06 15:30:09> mtp 2 16387 Rcvd SIO (Lnk 0)
<07/25/06 15:30:09> mtp 2 16387 Sent SIN (Lnk 0)
<07/25/06 15:30:09> mtp 2 16387 Rcvd SIO (Lnk 0)
<07/25/06 15:30:09> mtp 2 16387 Rcvd SIN (Lnk 0)
<07/25/06 15:30:11> mtp 2 16387 Timer 4 Expired (LINK 0 ALIGNED at layer 2)
<07/25/06 15:30:11> mtp 1 16387 Timer 4 Expired (LINK 0 ALIGNED at layer 2)
The middle column containing 1s and 2s identifies the board generating the alarm.